Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0035: Ist der Mauszeiger außerhalb des Objekts?

VB 5/6-Tipp 0035: Ist der Mauszeiger außerhalb des Objekts?

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: ClientToScreen, GetCursorPos

Download: Download des Beispielprojektes [6,39 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Bildfeld-Steuerelement "Picture1"
' Steuerelement: Timersteuerelement "Timer1"
' Steuerelement: Beschriftungsfeld "Label1"

Option Explicit

Private Declare Function GetCursorPos Lib "user32" _
        (lpPoint As POINTAPI) As Long
        
Private Declare Function ClientToScreen Lib "user32" _
        (ByVal hwnd As Long, lpPoint As POINTAPI) As Long
        
Private Type POINTAPI
  X As Long
  Y As Long
End Type

Dim P1 As POINTAPI
Dim P2 As POINTAPI

Private Sub Form_Load()
    Timer1.Enabled = False
    Timer1.Interval = 50
End Sub

Private Sub Timer1_Timer()
  Dim Result&, CurPos As POINTAPI

    Result = GetCursorPos(CurPos)

    If CurPos.X < P1.X Or CurPos.X > P2.X Or _
       CurPos.Y < P1.Y Or CurPos.Y > P2.Y Then
        Timer1.Enabled = False
        Label1.Caption = "Außerhalb"
    End If
End Sub

Private Sub Picture1_MouseMove(Button As Integer, Shift As _
                               Integer, X As Single, Y As Single)
  Dim Result&
                   
    If Timer1.Enabled = False Then
      P1.X = ScaleX(Picture1.Left, ScaleMode, vbPixels)
      P1.Y = ScaleY(Picture1.Top, ScaleMode, vbPixels)
        
      Result = ClientToScreen(hwnd, P1)
      P2.X = ScaleX(Picture1.Left + Picture1.Width, ScaleMode, vbPixels)
      P2.Y = ScaleY(Picture1.Top + Picture1.Height, ScaleMode, vbPixels)
        
      Result = ClientToScreen(hwnd, P2)
      Timer1.Enabled = True
      Label1.Caption = "Über dem Bild"
    End If
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 1 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.