Die Community zu .NET und Classic VB.
Menü

VB 5/6-Tipp 0105: MSFlexGrid, auf Spaltenweitenänderungen reagieren

 von 

Beschreibung 

Ein weiterer Nachteil des FlexGrids besteht darin, daß ein Ereignis fehlt, welches bei Veränderung einer Spaltenbreite ausgelöst wird. Wenn man aber das Control 'Subclassed' läßt sich dieses, durch Vergleich mit den in einem Feld gespeicherten Spaltenbreiten, beim Loslassen der rechten Maustaste, dann doch feststellen.

Schwierigkeitsgrad:

Schwierigkeitsgrad 2

Verwendete API-Aufrufe:

CallWindowProcA (CallWindowProc), SetWindowLongA (SetWindowLong)

Download:

Download des Beispielprojektes [3,01 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
' Die Komponente 'Microsoft FlexGrid Control 6.0 (MSFLXGRD.OCX)' wird benötigt.

'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Flexible Tabelle "MSFlexGrid1"

Option Explicit

Private ColWidth() As Integer

Private Sub Form_Load()
  Dim x%
  ReDim ColWidth(MSFlexGrid1.Cols - 1)
  
    For x = 0 To MSFlexGrid1.Cols - 1
      ColWidth(x) = MSFlexGrid1.ColWidth(x)
   Next x
   
   GridhWnd = MSFlexGrid1.hWnd
   Call Init
End Sub

Private Sub Form_Unload(Cancel As Integer)
  Call Terminate
End Sub

Public Sub MSFlexGrid1_ColResize()
  Dim x%, Dif&
  
    With MSFlexGrid1
      For x = 0 To .Cols - 1
        Dif = .ColWidth(x) - ColWidth(x)
        If Dif <> 0 Then
          Me.Caption = "Spalte " & x & " um " & Dif _
                       & " Twips geändert"
          ColWidth(x) = .ColWidth(x)
          Exit For
        End If
      Next x
    End With
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'--------- Anfang Modul "Module1" alias Module1.bas ---------

Option Explicit

Public Declare Function CallWindowProc Lib "user32" Alias _
       "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal _
       hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, _
       ByVal lParam As Long) As Long

Public Declare Function SetWindowLong Lib "user32" Alias _
       "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex _
       As Long, ByVal dwNewLong As Long) As Long

Const GWL_WNDPROC = -4
Const WM_LBUTTONUP = &H202

Public GridhWnd&
Dim PrevProc&

Public Sub Init()
  PrevProc = SetWindowLong(GridhWnd, GWL_WNDPROC, AddressOf WindowProc)
End Sub

Public Sub Terminate()
  Dim Result&
    Result = SetWindowLong(GridhWnd, GWL_WNDPROC, PrevProc)
End Sub

Function WindowProc(ByVal hWnd&, ByVal uMsg&, ByVal wParam&, ByVal _
                    lParam&) As Long
  WindowProc = CallWindowProc(PrevProc, hWnd, uMsg, wParam, lParam)
  If uMsg = WM_LBUTTONUP Then Form1.MSFlexGrid1_ColResize
End Function
'---------- Ende Modul "Module1" alias Module1.bas ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-VersionWin32sWin95Win98WinMEWinNT4Win2000WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version:

Windows-Version:

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 2 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von Fischer am 09.02.2011 um 14:34

Danke! Problem gelöst, klappt wunderbar.

Kommentar von rene sijbrant am 16.11.2001 um 23:22

Danke