Die Community zu .NET und Classic VB.
Menü

VB 5/6-Tipp 0135: Form-Systemmenü unterdrücken

 von 

Beschreibung 

Solange sich ein Programm sichtbar in der Taskleiste befindet, läßt sich das Systemmenü leider auch hiermit nicht vollständig unterbinden. Das formeigene, kann allerdings, wie hier gezeigt, durchaus unterdrückt werden. Dafür wird die Mausposition abgefragt und an entsprechender Stelle für Klicks unbrauchbar geschaltet.

Schwierigkeitsgrad:

Schwierigkeitsgrad 2

Verwendete API-Aufrufe:

CallWindowProcA (CallWindowProc), GetCursorPos, GetSystemMetrics, SetWindowLongA (SetWindowLong)

Download:

Download des Beispielprojektes [2,63 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Beschriftungsfeld "Label1"
Option Explicit

Private Sub Form_Load()
  Call Init(Me.hwnd)
End Sub

Private Sub Form_Unload(Cancel As Integer)
  Call Terminate(Me.hwnd)
End Sub




'---------- Ende Formular "Form1" alias Form1.frm  ----------
'--------- Anfang Modul "Module1" alias Module1.bas ---------

Option Explicit

Private Declare Function CallWindowProc Lib "user32" Alias _
        "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal _
        hwnd As Long, ByVal MSG As Long, ByVal wParam As _
        Long, ByVal lParam As Long) As Long
                
Private Declare Function SetWindowLong Lib "user32" Alias _
        "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex _
        As Long, ByVal dwNewLong As Long) As Long

Private Declare Function GetCursorPos Lib "user32" (lpPoint As _
        POINTAPI) As Long
        
Private Declare Function GetSystemMetrics Lib "user32" (ByVal _
        nIndex As Long) As Long

Public Type POINTAPI
  x As Long
  y As Long
End Type
 
Const SM_CXFRAME = 32
Const SM_CYFRAME = 33
Const SM_CYCAPTION = 4
 
Const WM_NCRBUTTONDOWN = &HA4
Const WM_NCLBUTTONDOWN = &HA1

Const GWL_WNDPROC = (-4&)

Dim PrevWndProc&

Private Function SubWndProc(ByVal hwnd As Long, ByVal MSG As Long, _
                            ByVal wParam As Long, ByVal lParam As _
                            Long) As Long
                              
  If Form1.WindowState <> vbMinimized Then
    If MSG = WM_NCLBUTTONDOWN Then
      If IsOverIcon Then
        SubWndProc = 0
        Exit Function
      End If
    ElseIf MSG = WM_NCRBUTTONDOWN Then
      SubWndProc = 0
      Exit Function
    End If
  End If
  SubWndProc = CallWindowProc(PrevWndProc, hwnd, MSG, wParam, lParam)
End Function

Public Sub Init(hwnd&)
  PrevWndProc = SetWindowLong(hwnd, GWL_WNDPROC, AddressOf SubWndProc)
End Sub

Public Sub Terminate(hwnd&)
  Call SetWindowLong(hwnd, GWL_WNDPROC, PrevWndProc)
End Sub

Public Function IsOverIcon() As Boolean
  Dim Result&, P As POINTAPI
  Dim FrameX&, FrameY&, TitleY&, FLeft&, FTop&
  
    Result = GetCursorPos(P)
    FLeft = Form1.ScaleX(Form1.Left, vbTwips, vbPixels)
    FTop = Form1.ScaleX(Form1.Top, vbTwips, vbPixels)
    FrameX = GetSystemMetrics(SM_CXFRAME) - 1
    FrameY = GetSystemMetrics(SM_CYFRAME) - 1
    TitleY = GetSystemMetrics(SM_CYCAPTION)
    
    If P.x > FLeft + FrameX And P.y > FTop + FrameY Then
      If P.y < FTop + FrameY + TitleY And _
         P.x < FLeft + FrameX + TitleY Then IsOverIcon = True
    End If
End Function
'---------- Ende Modul "Module1" alias Module1.bas ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-VersionWin32sWin95Win98WinMEWinNT4Win2000WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version:

Windows-Version:

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 1 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von Christian am 31.03.2003 um 19:49

Hallo
Ich hab das Programm ausprobiert, es funkt leider nicht, bzw ich bin mir auch nicht ganz sicher ob es auch so gemeint ist wie ich denke. Das Systemmenü ist das Menü, das erscheint, wenn man Strg+Altgr+Entf drückt?
Falls ja, dann funkt das Prog nicht, falls das allerdings n anderes Menü ist, dann ups, wie unterdrückt man dann das Menü? Was mach ich falsch mit dem Prog wenns nicht läuft?