Die Community zu .NET und Classic VB.
Menü

VB 5/6-Tipp 0158: Farbe des Pixels unter der Maus auf dem ganzen Bildschirm

 von 

Beschreibung 

Wer schon immer wissen wollte, welche Farbe das Pixel unter der Mausposition hat, wird hier bestens bedient. Das ist nicht nur auf das eigene Fenster beschränkt, sondern funktioniert bildschirmweit. Nebenher werden noch Informationen wie relative Bildschirmposition und Handle sowie Gerätekontext unter der Mausposition bestimmt.

Schwierigkeitsgrad:

Schwierigkeitsgrad 2

Verwendete API-Aufrufe:

BitBlt, GetCursorPos, GetDC, GetPixel, ReleaseDC, ScreenToClient, WindowFromPoint

Download:

Download des Beispielprojektes [2,55 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Bildfeld-Steuerelement "Picture1"
' Steuerelement: Timersteuerelement "Timer1"
' Steuerelement: Beschriftungsfeld "Label1"
' Steuerelement: Beschriftungsfeld "Label4"
' Steuerelement: Beschriftungsfeld "Label2"
' Steuerelement: Beschriftungsfeld "Label3"
' Steuerelement: Beschriftungsfeld "Label9" (Index von 0 bis 0)
' Steuerelement: Beschriftungsfeld "Label10" (Index von 1 bis 1)
' Steuerelement: Beschriftungsfeld "Label6" (Index von 2 bis 2)
' Steuerelement: Beschriftungsfeld "Label7" (Index von 3 bis 3)
' Steuerelement: Beschriftungsfeld "Label8" (Index von 4 bis 4)

Option Explicit

Private Declare Function BitBlt Lib "gdi32" (ByVal _
        hDestDC As Long, ByVal x As Long, ByVal y _
        As Long, ByVal nWidth As Long, ByVal nHeight _
        As Long, ByVal hSrcDC As Long, ByVal xSrc As _
        Long, ByVal ySrc As Long, ByVal dwRop As Long) _
        As Long
        
Private Declare Function GetCursorPos Lib "user32" _
        (lpPoint As POINTAPI) As Long
        
Private Declare Function GetDC Lib "user32" (ByVal _
        hWnd As Long) As Long
        
Private Declare Function GetPixel Lib "gdi32" (ByVal hDC _
        As Long, ByVal x As Long, ByVal y As Long) As Long
        
Private Declare Function ScreenToClient Lib "user32" _
        (ByVal hWnd As Long, lpPoint As POINTAPI) As Long
        
Private Declare Function WindowFromPoint Lib "user32" _
        (ByVal xPoint As Long, ByVal yPoint As Long) _
        As Long

Private Declare Function ReleaseDC Lib "user32" (ByVal hWnd _
        As Long, ByVal hDC As Long) As Long
        
Private Type POINTAPI
    x As Long
    y As Long
End Type

Private Sub Form_Load()
  Timer1.Interval = 50
  Timer1.Enabled = True
End Sub

Private Sub Timer1_Timer()
  Dim hWndp&, hDCp&, Result&, Pt As POINTAPI
  Static LastX&, LastY&

    Call GetCursorPos(Pt)
    If Pt.x = LastX And Pt.y = LastY Then Exit Sub
    LastX = Pt.x
    LastY = Pt.y
    
    Label1.Caption = "x-" & Pt.x & " y-" & Pt.y
    
    hWndp = WindowFromPoint(Pt.x, Pt.y)
    Label3.Caption = hWndp
    
    hDCp = GetDC(hWndp)
    Label4.Caption = hDCp
    
    Call ScreenToClient(hWndp, Pt)
    Label2.Caption = "x-" & Pt.x & " y-" & Pt.y
    
    Result = GetPixel(hDCp, Pt.x, Pt.y)
    If Result = -1 Then
      Call BitBlt(Picture1.hDC, 0, 0, 1, 1, hDCp, Pt.x, Pt.y, _
                  vbSrcCopy)
      Result = Picture1.Point(0, 0)
    End If
    
    Call ReleaseDC(hWndp, hDCp)
    Picture1.BackColor = Result
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-VersionWin32sWin95Win98WinMEWinNT4Win2000WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version:

Windows-Version:

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 5 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von Marko am 01.08.2009 um 18:57

Frage-1: Kann man das ganze in ein Modul verpacken?
Frage-2: Wie würde der Quelltext aussehen?
Oder geht das nicht, weil man suf dem Modul kein "Picture1" platzieren kann?
... vielleicht kann man das geschickt umgehen oder das Picture1 auf eine "extra-Form" platzieren!?
Höre gerne...
Gruß Marko

Kommentar von Tobias B am 11.09.2004 um 21:18

An Mario

Eine Farbe gibt man normalerweise in Hex an, z.b. &HFF6600

Dabei ist FF der Rot-,66 der blau- und 00 der Grün-Anteil

Kommentar von Mario Weichert am 29.10.2003 um 02:44

Frage: Kann man das irgendwie so umschreiben, das man da
gleich die RGB Werte des Pixels unter dem Cursor hat ?

Oder steht das da schon drinne und ich habe nur den Source
Code nicht verstanden. ( TYPISCH NEWBEE :-) )

Danke für die Antwort

Mfg
Mario

Kommentar von Roland am 05.06.2003 um 17:44

Hallo !
Wenn ich eine Linie mit der Farbe X (zB: 21712) zeichen, und dann mit diesem Programm die Farbe der Linie auslese, weicht die ausgelesene Farbe (als Zahlenwert in Variable Result) geringfügig ab (zB: 21974) Warum? Wie kann ich dass verhindern????
mfg Roland

Kommentar von Antonowski Emil am 24.05.2002 um 12:58

Es ist eine gute Funktion, doch sehr Ressourceverschwendend.