Die Community zu .NET und Classic VB.
Menü

VB 5/6-Tipp 0165: Markierungsrahmen ziehen und Bildausschnitt zoomen

 von 

Beschreibung 

Das hier vorgestellte Beispiel zeigt wie in VB Markierungsrahmen auf grafischen Objekten wie Pictureboxen etc. realisiert werden könnnen. Kern dabei ist der eingestellte DrawMode 10 (Stift XOR invers). Der auf diese Weise markierte Bildauschnitt kann hier in einem anderen Bild vergrößert dargestellt werden.

Schwierigkeitsgrad:

Schwierigkeitsgrad 2

Verwendete API-Aufrufe:

keine

Download:

Download des Beispielprojektes [16,48 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei PROJECT1.VBP -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Kontrollkästchen-Steuerelement "Check1"
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Horizontale Scrollbar "HScroll1"
' Steuerelement: Bildfeld-Steuerelement "Picture2"
' Steuerelement: Bildfeld-Steuerelement "Picture1"
' Steuerelement: Beschriftungsfeld "Label2"
' Steuerelement: Beschriftungsfeld "Label1"

Option Explicit

Dim Mode, X0&, Y0&, X1&, Y1&, X2&, Y2&, Zoom%
Dim l&, t&, h&, w&, Marked As Boolean

Private Sub Form_Load()
  Picture1.Picture = LoadPicture(App.Path & "\Bild.jpg")
  Zoom = 1
  Mode = 1
  Picture1.DrawMode = vbNotXorPen
  Picture1.DrawStyle = vbDash
End Sub

Private Sub Command1_Click()
  Printer.PaintPicture Picture2.Image, 0, 0, , , , , _
                       Picture2.Width, Picture2.Height
  Printer.EndDoc
End Sub

Private Sub Check1_Click()
  Command1.Enabled = IIf(Check1.Value = vbChecked, True, False)
End Sub

Private Sub Picture1_MouseDown(Button As Integer, Shift _
                               As Integer, X As Single, _
                               Y As Single)
  If Marked Then Call Markers
  
  If Mode = 1 Then
    X2 = X0
    Y2 = Y0
    Picture1.Line (X1, Y1)-(X2, Y2), , B
    
    X1 = X
    Y1 = Y
    
    X2 = X
    Y2 = Y
    Picture1.Line (X1, Y1)-(X2, Y2), , B
    
    X0 = X1
    Y0 = Y1
    Mode = 2
 End If
End Sub

Private Sub Picture1_MouseMove(Button As Integer, Shift _
                               As Integer, X As Single, _
                               Y As Single)
  If Mode = 2 Then
    X2 = X0
    Y2 = Y0
    Picture1.Line (X1, Y1)-(X2, Y2), , B
    
    X2 = X
    Y2 = Y
    Picture1.Line (X1, Y1)-(X2, Y2), , B
    
    X0 = X2
    Y0 = Y2
  End If
End Sub

Private Sub Picture1_MouseUp(Button As Integer, Shift As _
                             Integer, X As Single, Y As Single)
  Mode = 1
  If X2 < X1 Then
    l = X2
  Else
    l = X1
  End If
  
  If Y2 < Y1 Then
    t = Y2
  Else
    t = Y1
  End If
  
  w = Abs(X2 - X1)
  h = Abs(Y2 - Y1)
  
  If l < 0 Then l = 0
  If t < 0 Then t = 0
  
  If w = 0 Then w = 15
  If h = 0 Then h = 15
  
  If l + w > Picture1.Width Then w = Picture1.Width - l
  If t + h > Picture1.Height Then h = Picture1.Height - t
      
  Picture2.Width = w * Zoom
  Picture2.Height = h * Zoom
  Picture2.Refresh
  
  If Check1.Value = vbChecked Then Picture2.AutoRedraw = True
  
  Picture2.PaintPicture Picture1.Image, 0, 0, w * Zoom, _
                        h * Zoom, l, t, w, h
  
  If Check1.Value = vbChecked Then Picture2.AutoRedraw = False
  Call Markers
End Sub

Private Sub HScroll1_Change()
  Label1.Caption = HScroll1.Value
  Zoom = HScroll1.Value
End Sub

Private Sub Markers()
  Picture1.DrawStyle = 0
  Picture1.Line (l - 90, t - 90)-(l - 30, t - 30), 0, BF
  Picture1.Line (l - 90, t + h + 30)- _
                (l - 30, t + h + 90), 0, BF
  Picture1.Line (l + w + 30, t - 90)- _
                (l + w + 90, t - 30), 0, BF
  Picture1.Line (l + w + 30, t + h + 30)- _
                (l + w + 90, t + h + 90), 0, BF
  Picture1.DrawStyle = 1
  Marked = True
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei PROJECT1.VBP --------------

Tipp-Kompatibilität:

Windows/VB-VersionWin32sWin95Win98WinMEWinNT4Win2000WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version:

Windows-Version:

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 1 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von roland hohmann am 28.05.2005 um 11:34

Genau, was ich gesucht habe. Klappt bestens!