Die Community zu .NET und Classic VB.
Menü

VB 5/6-Tipp 0255: RGB-Farbanteile einer 24-Bit-Bitmap manipulieren

 von 

Beschreibung 

In einer 24-Bit Bitmap liegen die Farbanteile fein säuberlich in 3 Byte schritten aus einander. Diese Situation bietet sich förmlich dazu an einzelne Farbwerte gezielt zu ändern.Siehe auch Tipp 431 und Tipp 432

Schwierigkeitsgrad:

Schwierigkeitsgrad 2

Verwendete API-Aufrufe:

BitBlt, RtlMoveMemory (CopyMemory), GetObjectA (GetObject), VarPtr (VarPtrArray)

Download:

Download des Beispielprojektes [30,99 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Horizontale Scrollbar "HScroll1" (Index von 0 bis 2)
' Steuerelement: Bildfeld-Steuerelement "Picture1"
' Steuerelement: Bildfeld-Steuerelement "Picture2"
' Steuerelement: Beschriftungsfeld "Label3"
' Steuerelement: Beschriftungsfeld "Label2"
' Steuerelement: Beschriftungsfeld "Label1"


'Der Tip wird erst zur .exe kompiliert zum wahren Genuß!

Option Explicit

Private Declare Function BitBlt Lib "gdi32" (ByVal hDestDC As _
        Long, ByVal x As Long, ByVal y As Long, ByVal nWidth _
        As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, _
        ByVal xSrc As Long, ByVal ySrc As Long, ByVal dwRop As _
        Long) As Long

Private Declare Function GetObject Lib "gdi32" Alias _
        "GetObjectA" (ByVal hObject As Long, ByVal nCount As _
        Long, lpObject As Any) As Long

Private Declare Function VarPtrArray Lib "msvbvm50.dll" Alias _
        "VarPtr" (Ptr() As Any) As Long

Private Declare Sub CopyMemory Lib "kernel32" Alias _
        "RtlMoveMemory" (pDst As Any, pSrc As Any, ByVal _
        ByteLen As Long)

Private Type SAFEARRAYBOUND
  cElements As Long
  lLbound As Long
End Type

Private Type SAFEARRAY1D
  cDims As Integer
  fFeatures As Integer
  cbElements As Long
  cLocks As Long
  pvData As Long
  Bounds(0 To 0) As SAFEARRAYBOUND
End Type

Private Type SAFEARRAY2D
  cDims As Integer
  fFeatures As Integer
  cbElements As Long
  cLocks As Long
  pvData As Long
  Bounds(0 To 1) As SAFEARRAYBOUND
End Type


Private Type BITMAP
  bmType As Long
  bmWidth As Long
  bmHeight As Long
  bmWidthBytes As Long
  bmPlanes As Integer
  bmBitsPixel As Integer
  bmBits As Long
End Type

Private Const SRCCOPY = &HCC0020

Dim Brightness!, Contrast!
Dim TableBright(255) As Byte


Private Sub Form_Load()
  Picture1.Picture = LoadPicture(App.Path & "\Bild.jpg")
  Picture2.Picture = LoadPicture(App.Path & "\Bild.jpg")
End Sub

Private Sub HScroll1_Change(Index As Integer)
  Dim x%, Temp!
  
    Brightness = Exp(HScroll1(Index).Value / 50) / 5

    For x = 0 To 255
      Temp = x * Brightness
      If Temp > 255 Then Temp = 255
      TableBright(x) = Temp
    Next x
    
    Call MakeBitmap(Index)
    Picture1.Refresh
End Sub

Private Sub MakeBitmap(Color%)
  Dim Pic() As Byte, PicBuff() As Byte
  Dim SA As SAFEARRAY2D, Bmp As BITMAP
  Dim SABuff As SAFEARRAY2D, BmpBuff As BITMAP
  Dim x%, y%

    Call GetObject(Picture1.Picture, Len(Bmp), Bmp)
    Call GetObject(Picture2.Picture, Len(BmpBuff), BmpBuff)
  
    If Bmp.bmBitsPixel <> 24 Then
      MsgBox "Es werden nur 24-Bit Bitmaps unterstützt!"
      Exit Sub
    End If
    
    With SA
      .cbElements = 1
      .cDims = 2
      .Bounds(0).lLbound = 0
      .Bounds(0).cElements = Bmp.bmHeight
      .Bounds(1).lLbound = 0
      .Bounds(1).cElements = Bmp.bmWidthBytes
      .pvData = Bmp.bmBits
    End With
    
    Call CopyMemory(ByVal VarPtrArray(Pic), VarPtr(SA), 4)
        
    With SABuff
      .cbElements = 1
      .cDims = 2
      .Bounds(0).lLbound = 0
      .Bounds(0).cElements = BmpBuff.bmHeight
      .Bounds(1).lLbound = 0
      .Bounds(1).cElements = BmpBuff.bmWidthBytes
      .pvData = BmpBuff.bmBits
    End With
    
    Call CopyMemory(ByVal VarPtrArray(PicBuff), VarPtr(SABuff), 4)
    
    For x = 2 - Color To UBound(Pic, 1) Step 3
      For y = 0 To UBound(Pic, 2)
        Pic(x, y) = TableBright(PicBuff(x, y))
      Next y
    Next x
    
    Call CopyMemory(ByVal VarPtrArray(Pic), 0&, 4)
    Call CopyMemory(ByVal VarPtrArray(PicBuff), 0&, 4)
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-VersionWin32sWin95Win98WinMEWinNT4Win2000WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version:

Windows-Version:

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 1 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von Trabukh am 04.08.2004 um 10:59

Wie kann man es erreichen, dass das veränderte Bild in eine 2. Picturebox kopiert "geschrieben" wird?