Die Community zu .NET und Classic VB.
Menü

VB 5/6-Tipp 0461: ListView Header flach machen und optimale Breite einstellen

 von 

Beschreibung 

Wenn der User sowieso nicht die Möglichkeit haben soll, die Einträge einer ListView zu sortieren und es zudem unprofessionell aussieht, wenn das Klicken auf die Header-Schaltflächen keine Wirkung hat, können diese Schaltflächen auch flach gemacht werden. Zudem bietet dieser Tipp die Möglichkeit, die optimale Breite der Header automatisch auszuwählen.

Schwierigkeitsgrad:

Schwierigkeitsgrad 2

Verwendete API-Aufrufe:

GetWindowLongA (GetWindowLong), SendMessageA (SendMessage), SetWindowLongA (SetWindowLong), SetWindowPos

Download:

Download des Beispielprojektes [3,68 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Projekt1.vbp -------------
' Die Komponente 'Microsoft Windows Common Controls 5.0 (SP2) (COMCTL32.OCX)' wird benötigt.

'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command2"
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Listenansichtsetuerelement "ListView1"
Option Explicit

Private Sub Command1_Click()
    
    FlatListView ListView1, Me
    Command1.Caption = IIf(Command1.Caption = "Flache Spaltenköpfe", _
                       "Normale Spaltenköpfe", "Flache Spaltenköpfe")
    
End Sub

Private Sub Command2_Click()
    
    OptimalHeaderWidth ListView1
    
End Sub

Private Sub Form_Load()
    
    '//ListView auf Detail-Ansicht stellen
    ListView1.View = lvwReport
    
    '//Mit Einträgen füllen
    Dim lstItem As ListItem, i As Integer
    
    Randomize Timer
    For i = 1 To 10
        
        Set lstItem = ListView1.ListItems.Add(Text:="Neuer Eintrag" & CStr(i))
        lstItem.SubItems(1) = String$(Fix(Rnd * 25), Chr$(Int(Rnd * 26) + 65))
    Next i
    
End Sub


'---------- Ende Formular "Form1" alias Form1.frm  ----------
'--------- Anfang Modul "Module1" alias Module1.bas ---------
Option Explicit

Private Declare Function SendMessage Lib "user32" _
                         Alias "SendMessageA" ( _
                         ByVal hwnd As Long, _
                         ByVal wMsg As Long, _
                         ByVal wParam As Long, _
                         lParam As Any) As Long
                         
Private Declare Function GetWindowLong Lib "user32" _
                         Alias "GetWindowLongA" ( _
                         ByVal hwnd As Long, _
                         ByVal nIndex As Long) As Long
                         
Private Declare Function SetWindowLong Lib "user32" _
                         Alias "SetWindowLongA" ( _
                         ByVal hwnd As Long, _
                         ByVal nIndex As Long, _
                         ByVal dwNewLong As Long) As Long
                         
Private Declare Function SetWindowPos Lib "user32" ( _
                         ByVal hwnd As Long, _
                         ByVal hWndInsertAfter As Long, _
                         ByVal x As Long, _
                         ByVal y As Long, _
                         ByVal cx As Long, _
                         ByVal cy As Long, _
                         ByVal wFlags As Long) As Long
                         
Private Const GWL_STYLE = (-16) ' Fensterstil
Private Const LVM_SETCOLUMNWIDTH = &H101E ' gibt an, dass Spaltenbreite gesetzt werden
                                          ' soll
Private Const LVSCW_AUTOSIZE = (-1) ' automatisch optimale Spaltenbreite
Private Const LVSCW_AUTOSIZE_USEHEADER = (-2) ' sorgt dafür, dass alle
                                              ' Spaltenüberschriften lesbar sind
Private Const LVM_FIRST = &H1000
Private Const LVM_GETHEADER = (LVM_FIRST + 31) ' gibt Handle des ListViewHeaders zurück
Private Const HDS_BUTTONS As Long = &H2 ' Headerstil "Buttons"
Private Const SWP_NOMOVE As Long = &H2 ' Fenster nicht verschieben
Private Const SWP_NOSIZE As Long = &H1 ' Fenstergröße nicht ändern
Private Const SWP_NOZORDER As Long = &H4 ' Fensteranordnung (vorne, hinten) nicht ändern

Public Sub FlatListView(ByRef CListView As ListView, COwner As Form)

    Dim hHeader As Long, lStyle As Long
    
    hHeader = SendMessage(CListView.hwnd, LVM_GETHEADER, 0, 0)
    lStyle = GetWindowLong(hHeader, GWL_STYLE)
    lStyle = lStyle Xor HDS_BUTTONS
    
    If lStyle Then
    
        SetWindowLong hHeader, GWL_STYLE, lStyle
        
        SetWindowPos CListView.hwnd, COwner.hwnd, 0, 0, 0, 0, SWP_NOMOVE Or SWP_NOZORDER _
            Or SWP_NOSIZE
    End If
    
End Sub

Public Sub OptimalHeaderWidth(ByRef CListView As ListView)

    Dim i As Integer
    
    ' //Alle Spaltenköpfe durchgehen
    For i = 0 To CListView.ColumnHeaders.Count - 1
        SendMessage CListView.hwnd, LVM_SETCOLUMNWIDTH, i, -3
    Next i
    
End Sub


'---------- Ende Modul "Module1" alias Module1.bas ----------
'-------------- Ende Projektdatei Projekt1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-VersionWin32sWin95Win98WinMEWinNT4Win2000WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version:

Windows-Version:

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 3 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von gttries am 16.02.2004 um 11:59

Scheibar richtet sich OptimalHeaderWith nach den Einträgen und nicht nach der Kopfbreite. Wie lautet den der korrekte Code ?

Kommentar von am 21.05.2003 um 09:33

Tolles Ding. Kann man es noch so ergänzen, dass der User nicht die Möglichkeit hat, die Spaltenbreiten zu verändern?

Kommentar von Humbrie am 26.02.2002 um 20:59

Schaut nett aus, aber gehts auch mit Columnclick-event? Und vora ellem: das mit der optimalen Breite geht nicht mehr wenn man z.b. in die Listenansicht wechseln will. Da sind bei mir alle Einträge weg( zumindest optisch)