Startseite / Tipps / VB.NET-Tipp 0007: COM-Komponenten mit .NET schreiben

VB.NET-Tipp 0007: COM-Komponenten mit .NET schreiben

 von Herfried Wagner

' Dieser Quellcode stammt von http://www.activevb.de
' und kann frei verwendet werden. Für eventuelle Schäden
' wird nicht gehaftet.

' Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
' Ansonsten viel Spaß und Erfolg mit diesem Source!

' Projektversion:   Visual Studio 2002/2003
' Option Strict:    An
' Option Explicit:  An
'
' Referenzen: 
'  - System
'  - System.Windows.Forms
'  - System.Drawing
'

' ##############################################################################
' ################################# Person.vb ##################################
' ##############################################################################
Option Explicit On 
Option Strict On
Option Compare Binary

Imports System.Runtime.InteropServices
Imports System.Windows.Forms

' <remarks>
'   Stellt eine Person dar.
' </remarks>
'
' Hier wird ein fester GUID eingetragen, damit nicht 
' nach jedem Kompilieren die Referenz
' im VB6-Projekt aktualisiert werden muss. Der GUID 
' muss eindeutig sein, ein solcher
' GUID kann beispielsweise mit dem Tool Create 
' GUID aus dem Menü Extras, GUID erstellen,
' erstellt werden.
'
<Guid("D4664B41-5F86-4f68-A1F1-F454B4F93F31"), ComVisible(True)> _
Public Class Person
    Private m_strName As String

    ' <summary>
    '   Erstellt eine neue Instanz der Klasse.
    ' </summary>
    Public Sub New()
        m_strName = "Anonymous"
    End Sub

    ' <summary>
    '   Gibt eine Meldung in einem Meldungsfeld aus.
    ' </summary>
    '
    ' In COM sichtbar.
    '
    <ComVisible(True)> _
    Public Sub SayHelloToEverybody()
        MessageBox.Show(Name & " says ""Hello World from .NET!"".")
    End Sub

    ' <summary>
    '   Gibt eine Meldung in einem Meldungsfeld aus.
    ' </summary>
    '
    ' Nicht in COM sichtbar.
    '
    <ComVisible(False)> _
    Public Sub SayHelloToEverybodyExceptCOM()
        MessageBox.Show(Name & " says ""Hello World!"".")
    End Sub

    ' <summary>
    '   Gibt den Namen der Person und den in 
    '  <paramref name="strText"/> angebenenen Gedanken
    '   zurück.
    ' </summary>
    ' <param name="strText">Gedanke der Person.</param>
    ' <returns>Text, der den Gedanken der Person enthält.</returns>
    '
    ' In COM sichtbar.
    '
    <ComVisible(True)> _
    Public Function Think(ByVal strText As String) As String
        Return Name & " thinks """ & strText & """."
    End Function

    ' <summary>
    '   Gibt den Namen der Person an oder gibt ihn zurück.
    ' </summary>
    ' <value>Name der Person.</value>
    '
    ' In COM sichtbar.
    '
    <ComVisible(True)> _
    Public Property Name() As String
        Get
            Return m_strName
        End Get
        Set(ByVal Value As String)
            m_strName = Value
        End Set
    End Property
End Class

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 6 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

<ComClass(ComClass1.ClassId, ComClass1.InterfaceId, ComClass1.EventsId)> _
Public Class ComClass1

#Region "COM-GUIDs"
    ' Diese GUIDs stellen die COM-Identität für diese Klasse 
    ' und ihre COM-Schnittstellen bereit. Wenn Sie sie ändern, können vorhandene 
    ' Clients nicht mehr auf die Klasse zugreifen.
    Public Const ClassId As String = "47c78aae-fb9f-4013-a54f-e770f27ee339"
    Public Const InterfaceId As String = "772dd32e-fa2f-4b44-963a-d2f1677a219a"
    Public Const EventsId As String = "a88c5378-f5af-4df3-af62-e6ad4e01ba31"
#End Region

    ' Eine erstellbare COM-Klasse muss eine Public Sub New() 
    ' ohne Parameter aufweisen. Andernfalls wird die Klasse 
    ' nicht in der COM-Registrierung registriert und kann nicht 
    ' über CreateObject erstellt werden.
    Public Sub New()
        MyBase.New()
    End Sub
    Public Sub Test()
        MsgBox("Test")
    End Sub
End Class

<ComClassAttribute(clsNeu.ClassId, clsNeu.InterfaceId, clsNeu.EventsId)> _
Public Class clsNeu
  Public Const ClassId = "44558DD7-87AD-434f-9B1B-C478233D8C69"
  Public Const InterfaceId = "959A6835-4968-4cd5-89BE-7D408C2B46AA"
  Public Const EventsId = "02E3954F-5DC1-4ab9-9167-354F0EC2BCA3"

'...
End Class