Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0163: Bitmaps und Grafiken in der Titelleiste

VB 5/6-Tipp 0163: Bitmaps und Grafiken in der Titelleiste

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: BitBlt, GetSystemMetrics, GetWindowDC, ReleaseDC

Download: Download des Beispielprojektes [2,27 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Bildfeld-Steuerelement "Picture1"

Option Explicit

Private Declare Function ReleaseDC Lib "user32" (ByVal _
        hwnd As Long, ByVal hDc As Long) As Long
        
Private Declare Function BitBlt Lib "gdi32" (ByVal _
        hDestDC As Long, ByVal X As Long, ByVal Y As _
        Long, ByVal nWidth As Long, ByVal nHeight As _
        Long, ByVal hSrcDC As Long, ByVal xSrc As Long, _
        ByVal ySrc As Long, ByVal dwRop As Long) As Long
        
Private Declare Function GetWindowDC Lib "user32" (ByVal _
        hwnd As Long) As Long
        
Private Declare Function GetSystemMetrics Lib "user32" _
        (ByVal nIndex As Long) As Long

Const SM_CXFRAME = 32
Const SM_CYFRAME = 33
Const SM_CYCAPTION = 4
Const SRCCOPY = &HCC0020
Const SM_CXSIZE = 30

Dim FhDc&

Private Sub Form_Load()
  Dim X%
    Picture1.Width = 512 * 15
    For X = 0 To 255
      Picture1.Line (X, 0)-(X, Picture1.ScaleHeight), _
                     RGB(255 - X, 0, 0)
                     
      Picture1.Line (256 + X, 0)-(256 + X, Picture1.ScaleHeight), _
                     RGB(0, X, 0)
                     
      Picture1.PSet (X, Sin(X / (2 * 3.14)) * 8 + 9), _
                     RGB(0, 0, 255)
                     
      Picture1.PSet (X + 256, -Sin(X / (2 * 3.14)) * 8 + 9), _
                     RGB(0, 0, 255)
    Next X
    
    FhDc = Me.hDc
    FhDc = GetWindowDC(Me.hwnd)
End Sub

Private Sub Form_Resize()
  Dim FrameX&, FrameY&, ButtX&, CaptY&, CaptX&

    FrameX = GetSystemMetrics(SM_CXFRAME)
    FrameY = GetSystemMetrics(SM_CYFRAME)
    
    ButtX = GetSystemMetrics(SM_CXSIZE) * 3
    CaptX = Me.Width / Screen.TwipsPerPixelX - 2 * FrameX - ButtX
    CaptY = GetSystemMetrics(SM_CYCAPTION) - 1
    
    Call BitBlt(FhDc, FrameX, FrameY, CaptX, CaptY, _
                Picture1.hDc, 0, 0, SRCCOPY)
End Sub

Private Sub Form_Unload(Cancel As Integer)
  Call ReleaseDC(Me.hwnd, FhDc)
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 1 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.