Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0197: TextBox konsequent "locken"

VB 5/6-Tipp 0197: TextBox konsequent "locken"

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: CallWindowProcA (CallWindowProc), HideCaret, SetWindowLongA (SetWindowLong)

Download: Download des Beispielprojektes [2,99 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Textfeld "Text1"
Option Explicit

Private Declare Function HideCaret Lib "user32" (ByVal _
        hwnd As Long) As Long

Private Sub Form_Load()
  Text1.Text = "Das Schweinelendchen wird in ca. 3 bis 4 " & _
               "cm dicke Scheiben aufgeschnitten. In dem " & _
               "Öl und der Butter anbraten und garen. Mit" & _
               "einem Glas Calvados flambieren. Salzen un" & _
               "d mit frisch gemahlenem Pfeffer würzen un" & _
               "d warm stellen. Die geschälten Äpfel in V" & _
               "iertel schneiden und das Kerngehäuse hera" & _
               "usschneiden. In das Bratfett und die rest" & _
               "liche Butter geben und die Äpfel solange " & _
               "darin schmoren bis sie an-fangen zu zerfa" & _
               "llen. Mit dem restlichen Calva-dos übergi" & _
               "eßen und flambieren. Leicht mit Pfeffer w" & _
               "ürzen. Aus der Pfanne nehmen und warm ste" & _
               "llen."
  Call Init(Text1.hwnd)
End Sub

Private Sub Form_Unload(Cancel As Integer)
  Call Terminate(Text1.hwnd)
End Sub

Sub Text1_GotFocus()
  Call HideCaret(Text1.hwnd)
End Sub

'---------- Ende Formular "Form1" alias Form1.frm  ----------
'--------- Anfang Modul "Module1" alias Module1.bas ---------

Option Explicit

Private Declare Function CallWindowProc Lib "user32" Alias _
        "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal _
        hwnd As Long, ByVal MSG As Long, ByVal wParam As _
        Long, ByVal lParam As Long) As Long
                
Private Declare Function SetWindowLong Lib "user32" Alias _
        "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex _
        As Long, ByVal dwNewLong As Long) As Long

Const GWL_WNDPROC = (-4&)
Const WM_LBUTTONDOWN = &H201
Const WM_LBUTTONDBLCLK = &H203
Const WM_RBUTTONDOWN = &H204

Dim PrevWndProc&

Private Function SubWndProc(ByVal hwnd As Long, ByVal MSG As Long, _
                            ByVal wParam As Long, ByVal lParam As _
                            Long) As Long
                            
  If MSG = WM_LBUTTONDBLCLK Or MSG = WM_LBUTTONDOWN Or _
     MSG = WM_RBUTTONDOWN Then Exit Function

  SubWndProc = CallWindowProc(PrevWndProc, hwnd, MSG, wParam, lParam)
End Function

Public Sub Init(hwnd&)
  PrevWndProc = SetWindowLong(hwnd, GWL_WNDPROC, AddressOf SubWndProc)
End Sub

Public Sub Terminate(hwnd&)
  Call SetWindowLong(hwnd, GWL_WNDPROC, PrevWndProc)
End Sub
'---------- Ende Modul "Module1" alias Module1.bas ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 4 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.