Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0309: Einen animierten Cursor einbinden

VB 5/6-Tipp 0309: Einen animierten Cursor einbinden

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: GetCursor, LoadCursorA (LoadCursor), LoadCursorFromFileA (LoadCursorFromFile), ReleaseCapture, SetCapture, SetCursor

Download: Download des Beispielprojektes [3,17 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Timersteuerelement "Timer1"
' Steuerelement: Schaltfläche "Command1"

Option Explicit

Private Declare Function SetCapture Lib "user32" (ByVal hwnd _
        As Long) As Long
        
Private Declare Function ReleaseCapture Lib "user32" () As Long

Private Declare Function LoadCursor Lib "user32" Alias _
        "LoadCursorA" (ByVal hInstance As Long, ByVal lpCursorName _
        As String) As Long
        
Private Declare Function LoadCursorFromFile Lib "user32" Alias _
        "LoadCursorFromFileA" (ByVal lpFileName As String) As Long

Private Declare Function GetCursor Lib "user32" _
        () As Long

Private Declare Function SetCursor Lib "user32" (ByVal hCursor As _
        Long) As Long

Dim Flag As Boolean
Dim hAniCursor&, hOldCursor&

Private Sub Form_Load()
  Timer1.Enabled = False
End Sub

Private Sub Command1_Click()
  Flag = False
  Call InitAniCursor
  
  Do
    DoEvents
  Loop While Not Flag
  
  Call ExitAniCursor
End Sub

Private Sub Timer1_Timer()
  Static Cnt&
  
    If hAniCursor <> GetCursor Then
      Call SetCapture(Me.hwnd)
      Call SetCursor(hAniCursor)
    End If

    Cnt = Cnt + 1
    If Cnt > 80 Then
      Flag = True
      Cnt = 0
    End If
End Sub

Private Sub InitAniCursor()
  Timer1.Enabled = False
  Timer1.Interval = 50
  hAniCursor = LoadCursorFromFile(App.Path & "\cursor.ani")
  Call SetCapture(Me.hwnd)
  hOldCursor = SetCursor(hAniCursor)
  Timer1.Enabled = True
End Sub

Private Sub ExitAniCursor()
  Timer1.Enabled = False
  Call ReleaseCapture
  Call SetCursor(hOldCursor)
  hAniCursor = 0
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 6 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.