Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0312: Ein Kuchendiagramm mit der Pie-API erstellen

VB 5/6-Tipp 0312: Ein Kuchendiagramm mit der Pie-API erstellen

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: Pie

Download: Download des Beispielprojektes [2,33 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Kontrollkästchen-Steuerelement "Check1"

Option Explicit

Private Declare Function Pie Lib "gdi32" (ByVal hdc As _
        Long, ByVal x1 As Long, ByVal y1 As Long, ByVal _
        x2 As Long, ByVal y2 As Long, ByVal X3 As Long, _
        ByVal Y3 As Long, ByVal X4 As Long, ByVal Y4 _
        As Long) As Long

Private Type ELPRECTTYPE
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
  rX As Long
  rY As Long
  Mx As Long
  My As Long
End Type

Dim PiRad As Double

Private Sub Form_Load()
  Me.ScaleMode = vbPixels
  PiRad = 4 * Atn(1) / 180
End Sub

Private Sub Check1_Click()
  Call Form_Paint
End Sub

Private Sub Form_Paint()
  Dim elpRect As ELPRECTTYPE
  Dim x1&, y1&, x2&, y2&
  Dim WnkStart As Double, WnkEnde As Double, a As Double
                  
    Me.FillStyle = vbFSSolid
    With elpRect
      .Left = 10
      .Top = 10
      .Right = 210
      .Bottom = 90
      
      .rX = (.Right - .Left) / 2
      .rY = (.Bottom - .Top) / 2
      .Mx = .rX + .Left
      .My = .rY + .Top
         
      If Check1.Value = vbUnchecked Then
        Me.ForeColor = vbRed
      Else
        Me.ForeColor = vbBlack
      End If
      Me.FillColor = vbRed
      WnkStart = 0
      WnkEnde = 100
      Call GetXYfromAngle(.rX, .rY, .Mx, .My, WnkStart, x1, y1)
      Call GetXYfromAngle(.rX, .rY, .Mx, .My, WnkEnde, x2, y2)
      Call Pie(Me.hdc, .Left, .Top, .Right, .Bottom, _
                x1, y1, x2, y2)
         
         
      If Check1.Value = vbUnchecked Then Me.ForeColor = vbBlue
      Me.FillColor = vbBlue
      WnkStart = WnkEnde
      WnkEnde = 200
      Call GetXYfromAngle(.rX, .rY, .Mx, .My, WnkStart, x1, y1)
      Call GetXYfromAngle(.rX, .rY, .Mx, .My, WnkEnde, x2, y2)
      Call Pie(Me.hdc, .Left, .Top, .Right, .Bottom, _
                x1, y1, x2, y2)
      
      
      If Check1.Value = vbUnchecked Then Me.ForeColor = vbGreen
      Me.FillColor = vbGreen
      WnkStart = WnkEnde
      WnkEnde = 250
      Call GetXYfromAngle(.rX, .rY, .Mx, .My, WnkStart, x1, y1)
      Call GetXYfromAngle(.rX, .rY, .Mx, .My, WnkEnde, x2, y2)
      Call Pie(Me.hdc, .Left, .Top, .Right, .Bottom, _
                x1, y1, x2, y2)
      

      If Check1.Value = vbUnchecked Then Me.ForeColor = vbMagenta
      Me.FillColor = vbMagenta
      WnkStart = WnkEnde
      WnkEnde = 360
      Call GetXYfromAngle(.rX, .rY, .Mx, .My, WnkStart, x1, y1)
      Call GetXYfromAngle(.rX, .rY, .Mx, .My, WnkEnde, x2, y2)
      Call Pie(Me.hdc, .Left, .Top, .Right, .Bottom, _
                x1, y1, x2, y2)
    End With
End Sub

Private Sub GetXYfromAngle(rX&, rY&, Mx&, My&, _
                           Wnk As Double, x&, y&)
                           
  x = Sin(PiRad * Wnk) * rX + Mx
  y = Cos(PiRad * Wnk) * rY + My
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 3 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.