Die Community zu .NET und Classic VB.
Menü

VB 5/6-Tipp 0337: Daten zwischen Prozessen austauschen

 von 

Beschreibung 

Windows bietet viele Möglichkeiten, Nachrichten zwischen Prozessen und Fenstern auszutauschen, neben DDE, Winsock etc. ist dies ebenso ein recht interessantes und vor allem schnelles Verfahren. Es beruht auf einer Nachricht, die bei Erscheinen unter anderem einen Zeiger auf die übermittelten Daten mitbringen kann.

Dieser Tipp funktioniert entweder nur in kompilierter Form oder benötigt eine DLL/OCX-Datei. Diese Binärdateien sind dem Tipp hinzugefügt worden, um seinen Funktionsumfang darstellen zu können. Vor dem Upload wurden sie auf Viren geprüft.

Schwierigkeitsgrad:

Schwierigkeitsgrad 3

Verwendete API-Aufrufe:

CallWindowProcA (CallWindowProc), RtlMoveMemory (CopyMemory), FindWindowA (FindWindow), SendMessageA (SendMessage), SetWindowLongA (SetWindowLong)

Download:

Download des Beispielprojektes [9,77 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektgruppe Gruppe1.vbg -------------
'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command3"
' Steuerelement: Schaltfläche "Command2"
' Steuerelement: Schaltfläche "Command4"
' Steuerelement: Textfeld "Text1"
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Beschriftungsfeld "Label1"

Option Explicit

Private Declare Function FindWindow Lib "user32" Alias _
        "FindWindowA" (ByVal lpClassName As String, ByVal _
        lpWindowName As String) As Long

Private Declare Sub CopyMemory Lib "kernel32" Alias _
        "RtlMoveMemory" (hpvDest As Any, hpvSource As Any, _
        ByVal cbCopy As Long)

Private Declare Function SendMessage Lib "user32" Alias _
         "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, _
         ByVal wParam As Long, lParam As Any) As Long

Private Type COPYDATASTRUCT
    dwData As Long
    cbData As Long
    lpData As Long
End Type

Const WM_COPYDATA As Long = &H4A

Private Sub Form_Load()
    Call StartProcess
End Sub

Private Sub Command1_Click()
    Call SendData(1, Text1.Text)
End Sub

Private Sub Command2_Click()
    Call SendData(2)
End Sub

Private Sub Command3_Click()
    Call SendData(3)
End Sub

Private Sub Command4_Click()
    Call StartProcess
End Sub

Private Function SendData(Mode&, Optional Data$) As Boolean
    Dim DesthWnd As Long, B(0 To 255) As Byte
    Dim CD As COPYDATASTRUCT
    
    DesthWnd = FindWindow(vbNullString, "Destination")
    If DesthWnd = 0 Then
        MsgBox ("Das Zielfenster wurde nicht gefunden" & vbCrLf & _
                "Bitte Starten sie erst das andere Projekt!")
    Else
        CD.dwData = Mode
        Select Case Mode
            Case 1: SendData = True 'String senden
                Call CopyMemory(B(0), ByVal Data, Len(Data))
                CD.cbData = Len(Data) + 1
                CD.lpData = VarPtr(B(0))
                
            Case 2: SendData = True 'MsgBox anzeigen lassen
            Case 3: SendData = True 'Anderen Prozeß sich selbst
                                    'schließen lassen
        End Select
        
        If SendData Then Call SendMessage(DesthWnd, WM_COPYDATA, _
                                        Me.hwnd, CD)
    End If
End Function

Private Sub StartProcess()
    Call Shell(App.Path & "\Project2.exe", vbNormalNoFocus)
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------
'------------- Anfang Projektdatei Project2.vbp -------------
'--------- Anfang Formular "Form2" alias Form2.frm  ---------
' Steuerelement: Textfeld "Text1"
' Steuerelement: Beschriftungsfeld "Label1"
Option Explicit

Private Sub Form_Load()
    Call Init(Me.hWnd)
End Sub
      
Private Sub Form_Unload(Cancel As Integer)
    Call Terminate(Me.hWnd)
End Sub
'---------- Ende Formular "Form2" alias Form2.frm  ----------
'--------- Anfang Modul "Module2" alias Module2.bas ---------


Private Declare Sub CopyMemory Lib "kernel32" Alias _
        "RtlMoveMemory" (hpvDest As Any, hpvSource As Any, _
        ByVal cbCopy As Long)

Private Declare Function CallWindowProc Lib "user32" Alias _
         "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal _
         hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, _
         ByVal lParam As Long) As Long

Private Declare Function SetWindowLong Lib "user32" Alias _
        "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As _
        Long, ByVal dwNewLong As Long) As Long

Type COPYDATASTRUCT
    dwData As Long
    cbData As Long
    lpData As Long
End Type

Const GWL_WNDPROC As Long = -4&
Const WM_COPYDATA As Long = &H4A

Dim PrevWndProc As Long

Public Sub Init(hWnd As Long)
    PrevWndProc = SetWindowLong(hWnd, GWL_WNDPROC, _
                              AddressOf WindowProc)
End Sub

Public Sub Terminate(hWnd As Long)
    Call SetWindowLong(hWnd, GWL_WNDPROC, PrevWndProc)
End Sub

Private Function WindowProc(ByVal hWnd As Long, ByVal Msg As Long, _
    ByVal wParam As Long, ByVal lParam As Long) As Long
    
    If Msg = WM_COPYDATA Then
        Dim aa As String, B(0 To 255) As Byte
        Dim CD As COPYDATASTRUCT
        
        Call CopyMemory(CD, ByVal lParam, Len(CD))
        
        Select Case CD.dwData
        
        Case 1: Call CopyMemory(B(0), ByVal CD.lpData, CD.cbData)
                aa = StrConv(B, vbUnicode)
                aa = Left$(aa, InStr(1, aa, Chr$(0)) - 1)
                Form2.Text1.Text = Form2.Text1.Text & aa & vbCrLf
                
        Case 2: MsgBox ("MsgBox des Zielprozesses!")
        
        Case 3: Call Terminate(Form2.hWnd)
                Unload Form1
        End Select
    End If
          
    WindowProc = CallWindowProc(PrevWndProc, hWnd, Msg, wParam, lParam)
End Function
'---------- Ende Modul "Module2" alias Module2.bas ----------
'-------------- Ende Projektdatei Project2.vbp --------------
'-------------- Ende Projektgruppe Gruppe1.vbg --------------

Tipp-Kompatibilität:

Windows/VB-VersionWin32sWin95Win98WinMEWinNT4Win2000WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version:

Windows-Version:

Ihre Meinung  

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 17 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von anna am 01.04.2008 um 08:49

warum funktioniert es nicht wenn ich s mir kopiere

Kommentar von HeyJoe am 24.05.2006 um 17:13

Hallo,
Ich finde das ganze ziemlich gut.
Hatte allerdings ein paar Schwierigkeiten.

1.Die Beschreibung wie das Beispiel anzuwenden ist:
Für alle die ähnlich schwer von Begriff sind wie ich
Mein Reim auf das ganze:
Das Beispiel ist in zwei Teile geteilt:
A)Sender: Project1,Form1 usw.
B)Empfänger: Project2.exe (kompilierte Version)
Project2,Form2, Modul2...
(wird zum testen nicht eigentlich nicht
gebraucht, aber zum nachschauen wie der
Empfang abläuft)
über A)kann man alles starten : Project1 und die
Project2.exe
Nach dem Senden der Nachricht muß im Anzeigefeld von
Project2.exe eben die Nachricht erscheinen.
(-> tut sie dann auch).

2.WM -Problem:
Hat nichts mit der Weltmeisterschaft zu tun, sondern
mit WM_COPYDATA ( hab' viel Zeit im Internet verbracht,
aber so richtig erklärt wurde es nirgends.
mein Reim:
WM_COPYDATA hat eine Schalterfunktion (spezielle
Übertragungsart WM steht für WindowsMessage,
Rest ist unbekannt)
hängt mit der übertragenen Variablen
CD zusammen, die den COPYDATASTRUCT typ hat.

CD.dwData regelt die Übermittlungsart
1 -> String senden
2 -> eine MsgBox aus der Zielanwendung wird
aufgerufen
3 -> Zielanwendung schließt sich selbst
CD.cbData -> Länge der String-Nachricht +1
CD.lpData -> Pointer (Byte!) zeigt an eine Stelle eines
Speichers (wahrscheinlich ein spezieller
Speicher?) , in den die Nachricht zuvor
mit Hilfe der Api-Funktion
CopyMemory gespeichert wurde.

3.VBA Problem: me.hwnd gibt's hier nicht:
Lösung:


Private Function GetMyHwnd() As Long
'Source: Book: "Masterclass, Excel VBA, von Michael Schwimmer, S.388"
' leicht verändert
' Voraussetzung: die Apifunktion FindWindow muß schon deklariert sein!


Dim strCaption As String
Dim strSearchCaption As String

'Suchstring festlegen
strSearchCaption = "Umbennen ist nur ein Trick fuer Suche" ' Stichwort: eindeutige Fenstertitel

'Alte Caption speichern
strCaption = Me.Caption

'Suchstring als Caption
Me.Caption = strSearchCaption

'Handle ermitteln über API-Aufruf
GetMyHwnd = FindWindow(vbNullString, strSearchCaption)

'Alte Caption zurück
Me.Caption = strCaption
End Function

-> damit funktioniert das auch in VBA z.B. unter Excel...

4. Die Zielanwendung muß kompiliert sein (exe), damit das
die Nachricht übertragen wird. Jetzt würde mich halt auch interessieren, welche DLL oder OCX ich brauche damit man nicht kompilieren
muß ( da dies in VBA ohnehin nicht geht), woher ich sie bekomme,...

Möchte das Ganze zum Austausch zwischen VBA (Autocad) und einer Delphi-Anwendung verwenden.
In eine Richtung geht es schon von VBA zur Delphi-Exe (da kompiliert),
aber sollte auch umgekehrt gehen.

Für Hilfe und Antworten

schon mal vielen Dank
Joachim

Kommentar von Manfred1701 am 06.07.2005 um 16:14

Ich habe versucht dieses Beispiel auf VB.net zu übertragen. Leider erhalte ich nach einiger Zeit einwandfreier Funktion die Fehlermeldung
"Der Objektverweis wurde nicht auf eine Objektinstanz festgelegt".

Falls mir jemand helfen möchte würde ich den VB.net Code bzw. beide vollständigen Projekte gerne zur Verfügung stellen.

Mail bitte auch an M.Boehm@b-b-i.de

Gruß

Manfred1701

Kommentar von TheMetatron am 26.04.2005 um 20:17

Also, ich habe folgendes vor: Durch dieses oben genannte Verfahren möchte ich zwei Progs mit einander kommunizieren lassen. Soweit nichts ungewöhnliches. Eins der Programm Delphi, anderes VB. Da ich das Delphi Programm schreibe und jemand Anderes das VB Programm, bräuchte ich jetzt mal den obigen Code compiliert. Das 'Beispielprojekt' enthält ja nur den Empfänger (wieso?)..Könnte mir jemand den Sender schicken? (newton@dacg.de)

mfg

Thomas

Kommentar von WSyS am 20.03.2005 um 21:12

In Projekt2 --> Module2 --> Private Function WindowProc --> Case1 hab ich einen Fehler gefunden

Es gehört statt:
Form1.Text1.Text = Form1.Text1.Text & aa & vbCrLf

das:
Form2.Text1.Text = Form2.Text1.Text & aa & vbCrLf

mfg. WSyS

Kommentar von Herrmann am 15.03.2005 um 15:54

Im Kommentar zum Tipp 0337: Daten zwischen Prozessen austauschen ist die Rede von benötigten DLL/OCX-Dateien, die offenbar der EXE hinzugefügt wurden.
Um welche Dateien handelt es sich?
Sind diese frei verfügbar?


Mit freundlichen Grüßen,
Herrmann

Kommentar von steppi am 01.02.2005 um 15:30

kann man damit auch zwischen zwei verschiedenen Rechner übers Netz kommunizieren?

Kommentar von M.Mattern am 02.08.2004 um 15:35

Mail vom 29.07.04
Fehler gefunden -> im Projekt 2 im BAS-Modul wird auf eine falsche Form gezeigt -> Fehlermitteilung wg. fehlendem Objekt!
MfG M.Mattern

Kommentar von Mathias Mattern am 29.07.2004 um 11:27

Hallo, beim Ausprobieren bin ich auf folgende Fragen gestoßen:
1. Wieso fragt das Project2 beim erstellen der "EXE" nach der Startform? Das Eintragen der Form2 als Startobject führt immer zu Fehler beim Senden von Mitteilungen...
2. Wieso ist meine (ebenfalls nicht funktionsfähige) Project2.exe 20k lang und das Orginal nur 12k ?

Danke im Voraus für die Antworten...

Mit freundlichen Grüßen
M. Mattern

Kommentar von markus am 26.08.2003 um 21:49

an azmo:
wenn du interprozesskommunikation betreiben willst, MUß irgendein Protokoll her, da beiden (Server UND Client) sagt, wie was warum und wo zu 'bequatschen' ist.
Das mit der MsgBox war auch nur ein Beispiel. Wenn Dein 'fremdes Proggi' nirgends gesagt bekommt, daß es auf Nachricht X eine MsgBox mit dem Text Y anzeigen soll, kannst Du es mit Messages zubomben - es ignoriert das einfach.

dein client muß logischerweise auch subclassing (also hijacken der winproc) unterstützen, damit es überhaupt reagieren kann. wie die reaktion dann aussieht, liegt an dir. und wenn kein source da ist, ist das dumm gelaufen ;)

ähnlich kannst du auch sagen 'ich mache IP-Com über winsock'.. wenn du im client kein winsock verwendest wird das nie funktionieren (auch die art dem kommunikation (winsock, pipe, messages, etc. wird mit dem 'Protokoll' definiert).

Trotzdem finde ich das hier gezeigte sehr unelegant.
Hat jemand Interprozess-Kommunikation schonmal über (anonyme) Pipes (bidrektional) hinbekommen?

Ich hab vor einen INETD (wie unter Linux) auch mal unter VB zu bauen. Nur stellt sich die Frage, wie man am elegantesten mit einem anderen Prog kommuniziert.
Linux ist da klasse: stdout, stdin und fertig - funktioniert immer; gibt's sowas auch unter windows!? Weil Pipes bringen auch wieder ihre 'nachteile' mit ins spiel.

ich glaub, die Fragestellung war falsch;) - Gibt's ein VB auch für unter Linux ;) ?


Kommentar von Michael am 25.07.2003 um 00:41

Wie kann ich mit dem Programm ein ganzes (String-) Array auf einmal an ein anderes Programm übermitteln, ohne jedes Element einzeln übermitteln zu müssen?

Kommentar von azmo am 25.05.2003 um 13:59

hmm funzt jo... zwischen dem proggi (client) und dem zielprogramm (server) recht gut, nur was ist wenn das zielprogramm dieses modul nicht hat?

sagen wir ich habe ein programm welches in XYZ geschrieben ist, und ich von diesem programm keinen source vorliegen hab. Nun pop't bei dem proggi eine message box mit textfeld auf, in die ich was eintragen soll... leider mit diesem programm nicht machbar, da auf dem programm das "server" modul fehlt.

Kommentar von Rumsdibumms am 20.05.2003 um 13:19

Also ich glaub an diese Meinung kann ich mich anschliessen:
Ich sehe in dem Programm überhaupt keine Sinn. Egal was man macht, es passiert sozusagen ... NIX.

Kommentar von S.Kallenberger am 02.01.2003 um 18:03

Wie kann man eigentlich mit Hilfe dieses Programms von einem VB- an ein C++-Programm Nachrichten übertragen ?

Kommentar von Cyrus am 13.09.2002 um 17:54

Das hat mit dem internen Nachrichtensystem von Windows zu tun. Wenn ein VB-Programm startet, erstellt VB eine "Hauptprocedur", an welche alle Nachriten von Windows (und das sind ziemlich viele) geschickt wird. Im obigen Source wird diese Proc. erstmals durch eine eigene ersetzt. So ist es möglich, dass das Programm ohne Schleife etc. auf die Nachrichten reagiert.

Kommentar von Hendrik Jordt am 31.08.2002 um 12:38

Das ist eine gute Frage...
Ich sehe in dem Programm überhaupt keine Sinn. Egal was man macht, es passiert sozusagen ... NIX.

Kommentar von E.Leinen am 28.05.2001 um 09:17

Wieso registriert das Programm, das Daten empfängt, daß Daten an das Handle seines Fensters gesendet werden? Einen Timer, eine Schleife die Nachrichten abfragt, ist nicht vorhanden.