Startseite / Tipps / VB 5/6-Tipp 0347: Läuft ein Programm als Exe oder in der IDE?

VB 5/6-Tipp 0347: Läuft ein Programm als Exe oder in der IDE?

 von ActiveVB

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Rahmensteuerelement "Frame1"
' Steuerelement: Schaltfläche "Command2" auf Frame1
' Steuerelement: Schaltfläche "Command1" auf Frame1
' Steuerelement: Beschriftungsfeld "Label1" auf Frame1

Option Explicit

Private Declare Function GetWindow Lib "user32" (ByVal hwnd As _
        Long, ByVal wCmd As Long) As Long
        
Private Declare Function GetClassName Lib "user32" Alias _
        "GetClassNameA" (ByVal hwnd As Long, ByVal lpClassName _
        As String, ByVal nMaxCount As Long) As Long

Const GW_OWNER = 4

Private Sub Form_Load()
  Call CheckGoodWay
End Sub

Private Sub Command2_Click()
  Call CheckBadWay
End Sub

Private Sub Command1_Click()
  Call CheckBadWay
End Sub

Private Sub CheckGoodWay()
  Dim aa$
  
    If IsRunningInIDE Then
      aa = "Dieses Programm läuft derzeit in der IDE!"
    Else
      aa = "Diese Programm läuft als komplierte Exe!"
    End If
    
    MsgBox (aa)
End Sub

Private Sub CheckBadWay()
  Dim aa$
  
    If IsRunningInIDE_DirtyTrick Then
      aa = "Dieses Programm läuft derzeit in der IDE!"
    Else
      aa = "Diese Programm läuft als komplierte Exe!"
    End If
    
    MsgBox (aa)
End Sub

'Die saubere Methode, Nachteil: Soll der ausführungszustand
'in einer fensterlosen Komponente getestet werden, wie z.B.
'DLLs oder OCXen, muß zwecks Prüfung das Fensterhandle des
'die Komponente aufrufenden Fensters mit an die Komponente
'übergeben werden.
Private Function IsRunningInIDE() As Boolean
  Dim Buffer$, ParenthWnd&
    
    Buffer = Space(128)
    ParenthWnd = GetWindow(Me.hwnd, GW_OWNER)
    Call GetClassName(ParenthWnd, Buffer, Len(Buffer))
    
    If Left(Buffer, 11) = "ThunderMain" Then
      IsRunningInIDE = True
    Else
      IsRunningInIDE = False
    End If
End Function

'Die zweite Methode: Funktioniert immer, auch in Komponenten
'Hier muß kein Handle an eine fensterlose Komponente überge-
'ben werden. Ein guter Stil ist das allerdings nicht.
Private Function IsRunningInIDE_DirtyTrick() As Boolean
  On Error Goto NotCompiled
  
    Debug.Print 1 / 0
    Exit Function
    
NotCompiled:
    IsRunningInIDE_DirtyTrick = True
    Exit Function
End Function

'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-Version	Win32s	Win95	Win98	WinME	WinNT4	Win2000	WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version: VB6 VB5 VB4

Windows-Version: Windows XP Windows 2000 Windows NT4 Windows Me Windows 98 Windows 95 Win32s

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 8 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Public Function isIDE () As Boolean 
  Debug.Assert (isIDE=True)
'das wars ...da die Debug-Kommandos in der EXE nicht
'ausgeführt werden, liefert diese Funtion dann FALSE.
End Function