VB 5/6-Tipp 0366: MultiSelect im CommonDialog zulassen und auslesen

von ActiveVB

Beschreibung

Hier eine bedingte Lösung zum Problem der Mehrfachauswahl im ComDlg. Bedingt deshalb, da versucht wird sämtliche markierte Files plus des Pfades für alle, in einen maximal 32767 Byte großen String zu packen. Ist eine größere Länge erforderlich, werden die übriggebliebenen Dateien einfach nicht mitübergeben.

Schwierigkeitsgrad:

Schwierigkeitsgrad 2

Verwendete API-Aufrufe:

keine

Download:

Download des Beispielprojektes [2,56 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
' Die Komponente 'Microsoft Common Dialog Control 6.0 (SP3) (comdlg32.ocx)' wird benötigt.

'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Standarddialog-Steuerelement "CommonDialog1"
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Listen-Steuerelement "List1"

Option Explicit

Private Sub Command1_Click()
    Dim Flag As Boolean
    Dim aa As String, bb As String, Path As String
    Dim Mem As Boolean
    Dim Pos As Long, x As Long
    
    On Error Goto Break
    
    With CommonDialog1
        .FileName = ""
        .CancelError = True
        .Flags = cdlOFNAllowMultiselect Or cdlOFNExplorer
        .ShowOpen
        
        If Flag Then
            Call MsgBox("Es wurde 'Abbrechen' gewählt!")
        Else
            List1.Clear
        
            'Schauen ob evt. nur eine Datei ausgewählt wurde
            If InStr(.FileName, Chr$(0)) <> 0 Then
                aa = .FileName & Chr$(0)
                Pos = 1
                
                Do
                    'Chr$(0) ist Trennzeichen
                    x = InStr(Pos, aa, Chr$(0))
                    
                    If x = 0 Then Exit Do
                    bb = Mid$(aa, Pos, x - Pos)
                    
                    If Not Mem Then
                        'Im ersten Teil befindet sich immer der Pfad
                        Path = bb
                        Mem = True
                    Else
                        'Pfad ist bereits bekannt, es folgen Dateinamen
                        List1.AddItem Path & "\" & bb
                    End If
                    Pos = x + 1
                Loop
            Else
                'Es wurde nur eine Datei ausgewählt
                List1.AddItem .FileName
            End If
        End If
    End With
    Exit Sub
  
Break:
    If Err.Number = 32755 Then
      Flag = True
      Resume Next
    ElseIf Err.Number = 20476 Then Flag = True
      Call MsgBox("Es wurden zu viele Dateien ausgewählt!")
    End If
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Tipp-Kompatibilität:

Windows/VB-Version	Win32s	Win95	Win98	WinME	WinNT4	Win2000	WinXP
VB4
VB5
VB6

Ihre Meinung

Falls Sie Fragen zu diesem Artikel haben oder Ihre Erfahrung mit anderen Nutzern austauschen möchten, dann teilen Sie uns diese bitte in einem der unten vorhandenen Themen oder über einen neuen Beitrag mit. Hierzu können sie einfach einen Beitrag in einem zum Thema passenden Forum anlegen, welcher automatisch mit dieser Seite verknüpft wird.

Archivierte Nutzerkommentare

Klicken Sie diesen Text an, wenn Sie die 7 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.

Kommentar von Luis Oliveira am 06.09.2005 um 13:38

DIM LONF as String

LONF = Split(.FileName, Chr$(0))

Kommentar von Shredher am 03.10.2004 um 19:58

Hi, bin zwar etwas spät dran um die Frage zu beantworten, aber vielleicht interessiert das andere ja auch noch:

TO SIMON:
Also, was das wieder abschalten des Multiselect betrifft, weis ich auch nicht so recht... was ich aber rausgefunden hab, wenn man ihn irgendein Pseudo-Flag oder anderes Flag gibt, ist das Multiselect wieder abgeschaltet

TO SASCHA:
Ja das geht:
Das Array musst du allerdinsgs vorher als String deklarieren

Dim FileArray() as String

FileArray() = Split(CommonDialog1.FileName,CHR$(0))

for x = 1 to Ubound(FileArray)
ListBox.AddItem (FileArray(0) & "\" & FileArray(x))
next x

Ubound gibt immer den obersten Grenzwert eines Arrays zurück. D.H. wenn du dem Array zuvor eine feste Größe gibst, wirst du mit Ubound auch diese erhalten.

FileArray(0) ist immer der Pfad, wenn du die Split-Funktion verwendest. Alle Felder > 0 sind dann die Dateien... Deshalb fängt auch die Schleife mit 1 an und nicht wie sonst bei Arrays mit 0

Ich hoffe das Hilft
Gruß Shredher

Kommentar von Simon am 29.08.2003 um 13:14

Der Tipp ist super!
mein Problem ist aber nun, das ich bei späterer Verwendung (save-dialog) das Multiselect wider aushaben muss. Ich kann zwar nen zweites commondialog objekt einbinden, aber das will ich nach möglichkeit vermeiden.
Weiß als jemand zufällig wie ich multiselect wider aus bekomme??

mfg Simon

Kommentar von Uwe am 19.08.2001 um 13:17

Auf folgender Seite ist beschrieben wie man "unendlich" viele Files wählen kann
http://www.mvps.org/vbnet/index.html?http://www.mvps.org/vbnet/faq/main/cdlgmultiselect.htm
MfG, Uwe

Kommentar von Sascha am 03.06.2001 um 15:33

Bei Split, wie kann ich dann sehen, wieviele Werte im Array sind? Also, wie oft ich nachher eine Schleife durchlaufen lassen muss, um alle aufzulisten

Kommentar von Götz Reinecke am 16.02.2001 um 16:05

Sicherlich, nur hat nicht jeder VB6, ich z.B. nutze VB5 und da gibts leider keine Split Funktion.
Grüße
Götz

Kommentar von Z-BAD am 16.02.2001 um 15:51

Wäre es nicht leichter die Split()-Funktion zu benutzen?
Dim strDatei() as string
strDatei() = Split(CommonDialog1.filename,Chr(0))
Z-BAD