Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0385: Icons in Subitems eines Listviews ermöglichen

VB 5/6-Tipp 0385: Icons in Subitems eines Listviews ermöglichen

 von Mathias Schnarrenberger

Schwierigkeitsgrad:

Verwendete API-Aufrufe: SendMessageA (SendMessage), SendMessageA (SendMessageLong)

Download: Download des Beispielprojektes [5,17 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
' Die Komponente 'Microsoft Windows Common Controls 6.0 (SP6) (mscomctl.ocx)' wird benötigt.

'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Bilderlistenelement "ImageList1"
' Steuerelement: Listenanzeigesteuerungselement "ListView1"
' Steuerelement: Schaltfläche "Command1"


'Autor: Mathias Schnarrenberger
'E-Mail: schnarrenberger@t-online.de

Option Explicit

Private Declare Function SendMessageLong Lib "user32" Alias _
        "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, _
        ByVal wParam As Long, ByVal lParam As Long) As Long
        
Private Declare Function SendMessage Lib "user32" Alias _
        "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, _
        ByVal wParam As Long, lParam As Any) As Long

Private Type LVITEM
    mask As Long
    iItem As Long
    iSubItem As Long
    state As Long
    stateMask As Long
    pszText As String
    cchTextMax As Long
    iImage As Long
    lParam As Long
    iIndent As Long
End Type

Private Const LVM_FIRST As Long = &H1000&
Private Const LVM_GETEXTENDEDLISTVIEWSTYLE As Long = (LVM_FIRST + 55)
Private Const LVM_SETEXTENDEDLISTVIEWSTYLE As Long = (LVM_FIRST + 54)
Private Const LVS_EX_SUBITEMIMAGES As Long = &H2&
Private Const LVIF_IMAGE As Long = &H2&
Private Const LVM_SETITEM As Long = (LVM_FIRST + 6)

Private Sub Form_Load()
    With ListView1
        .ListItems.Add 1, , "Eintrag 1", 1, 1
        .ListItems.Add 2, , "Eintrag 2", 2, 2
        .ListItems.Add 3, , "Eintrag 3", 3, 3
        
        .ListItems.Item(1).SubItems(1) = "Eintrag 1B"
        .ListItems.Item(1).SubItems(2) = "Eintrag 1C"
        
        .ListItems.Item(2).SubItems(1) = "Eintrag 2B"
        .ListItems.Item(2).SubItems(2) = "Eintrag 2C"
        
        .ListItems.Item(3).SubItems(1) = "Eintrag 3B"
        .ListItems.Item(3).SubItems(2) = "Eintrag 3C"
    End With
End Sub

Private Sub Command1_Click()
    Call SetLVSubImages(ListView1, 1, 1, 3, True)
    Call SetLVSubImages(ListView1, 1, 2, 6, True)
    
    Call SetLVSubImages(ListView1, 2, 1, 4, True)
    Call SetLVSubImages(ListView1, 2, 2, 7, True)
    
    Call SetLVSubImages(ListView1, 3, 1, 5, True)
    Call SetLVSubImages(ListView1, 3, 2, 8, True)
End Sub

Private Sub SetLVSubImages(LV As ListView, ByVal Index, ByVal Column As Long, _
    ByVal Image As Long, ByVal SubImagesOn As Boolean)
    
    Dim lvStyle As Long, LV_Item As LVITEM
    
    lvStyle = SendMessageLong(LV.hwnd, _
              LVM_GETEXTENDEDLISTVIEWSTYLE, 0, 0)
    
    If SubImagesOn Then
        lvStyle = lvStyle Or LVS_EX_SUBITEMIMAGES
    Else
        lvStyle = lvStyle And Not LVS_EX_SUBITEMIMAGES
    End If
    
    Call SendMessageLong(LV.hwnd, _
         LVM_SETEXTENDEDLISTVIEWSTYLE, 0, lvStyle)
    
    If SubImagesOn Then
        With LV_Item
            .mask = LVIF_IMAGE
            .iSubItem = Column
            .iItem = Index - 1
            .iImage = Image
        End With
        
        Call SendMessage(LV.hwnd, LVM_SETITEM, Index - 1, LV_Item)
    End If
    
    LV.Refresh
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 5 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.