Startseite / Tipps / VB 5/6-Tipp 0458: Existiert eine Funktion in einer DLL

VB 5/6-Tipp 0458: Existiert eine Funktion in einer DLL

 von Benjamin Wilger

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'-------- Anfang Projektdatei IsFunctionExported.vbp --------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Textfeld "Text2"
' Steuerelement: Textfeld "Text1"
' Steuerelement: Beschriftungsfeld "Label2"
' Steuerelement: Beschriftungsfeld "Label1"
Option Explicit

Private Declare Function GetModuleHandle Lib "kernel32" _
                         Alias "GetModuleHandleA" ( _
                         ByVal lpModuleName As String) As Long
                         
Private Declare Function LoadLibrary Lib "kernel32" _
                         Alias "LoadLibraryA" ( _
                         ByVal lpLibFileName As String) As Long
                         
Private Declare Function GetProcAddress Lib "kernel32" ( _
                         ByVal hModule As Long, _
                         ByVal lpProcName As String) As Long
                         
Private Declare Function FreeLibrary Lib "kernel32" ( _
                         ByVal hLibModule As Long) As Long
                         
Private Sub Command1_Click()
    If IsFunctionExported(Text2.Text, Text1.Text) Then
        MsgBox ":)" & vbCrLf & "Die Funktion wird von der DLL unterstützt!"
    Else
        MsgBox ":(" & vbCrLf & "Diese Funktion wird von der DLL leider nicht unterstützt!"
    End If
End Sub

' Diese Funktion überprüft, ob die angegebene Function von einer DLL exportiert wird.
Private Function IsFunctionExported(ByVal sFunction As String, ByVal sModule As String) _
    As Boolean
    
    Dim hMod As Long, Loaded As Boolean
    
    ' Handle der DLL erhalten
    hMod = GetModuleHandle(sModule)
    
    If hMod = 0 Then ' Falls DLL nicht registriert ...
        hMod = LoadLibrary(sModule) ' DLL in den Speicher laden.
        If hMod Then Loaded = True
    End If
    
    If hMod Then
        If GetProcAddress(hMod, sFunction) Then IsFunctionExported = True
    End If
    
    If Loaded Then Call FreeLibrary(hMod)
End Function

'---------- Ende Formular "Form1" alias Form1.frm  ----------
'--------- Ende Projektdatei IsFunctionExported.vbp ---------

Tipp-Kompatibilität:

Windows/VB-Version	Win32s	Win95	Win98	WinME	WinNT4	Win2000	WinXP
VB4
VB5
VB6

Hat dieser Tipp auf Ihrem Betriebsystem und mit Ihrer VB-Version funktioniert?

Ja, funktioniert!

Nein, funktioniert nicht bei mir!

VB-Version: VB6 VB5 VB4

Windows-Version: Windows XP Windows 2000 Windows NT4 Windows Me Windows 98 Windows 95 Win32s

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 7 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.