Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0478: Gestartetes Programm nach vorgegebenen Zeitraum schließen

VB 5/6-Tipp 0478: Gestartetes Programm nach vorgegebenen Zeitraum schließen

 von ActiveVB

Schwierigkeitsgrad:

Verwendete API-Aufrufe: CloseHandle, OpenProcess, TerminateProcess

Download: Download des Beispielprojektes [3,05 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei tempprog.vbp -------------
' Die Komponente 'Microsoft Common Dialog Control 6.0 (SP3) (COMDLG32.OCX)' wird benötigt.

'---- Anfang Formular "frmProgRun" alias frmProgRun.frm  ----
' Steuerelement: Textfeld "txtZeit"
' Steuerelement: Schaltfläche "cmdStart"
' Steuerelement: Standarddialog-Steuerelement "cdcProgramm"
' Steuerelement: Schaltfläche "cmdWählen"
' Steuerelement: Textfeld "txtProgramm"
' Steuerelement: Timersteuerelement "Timer"
' Steuerelement: Beschriftungsfeld "Label2"
' Steuerelement: Beschriftungsfeld "Label1"
' Steuerelement: Beschriftungsfeld "lblHilfe"
Option Explicit

Private Declare Function TerminateProcess Lib "kernel32" ( _
                         ByVal hProcess As Long, _
                         ByVal uExitCode As Long) As Long
                         
Private Declare Function OpenProcess Lib "kernel32" ( _
                         ByVal dwDesiredAccess As Long, _
                         ByVal bInheritHandle As Long, _
                         ByVal dwProcessId As Long) As Long

Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long

Const PROCESS_TERMINATE = &H1

Private ProcessId As Long
Private ProcessId_Exit As Long
Private RetVal As Variant

Private Sub cmdStart_Click()
    
    If txtProgramm.Text <> "" Then
        
        ProcessId = Shell(txtProgramm.Text, vbNormalFocus)
        'Shell startet das ausgewählte Programm.
        
        Timer.Interval = CInt(txtZeit.Text) * 1000
        'Timer Interval einstellen.
        
    End If
    
End Sub

Private Sub cmdWählen_Click()
    
    cdcProgramm.ShowOpen
    txtProgramm.Text = cdcProgramm.FileName
    'Mit Hilfe des Common Dialog Controls können
    'Sie hier ein Programm auswählen.
    
End Sub

Private Sub Timer_Timer()
    
    ProcessId_Exit = OpenProcess(PROCESS_TERMINATE, 0&, ProcessId)
    'Mit dieser Funktion erhalten Sie das Object-Handle auf den
    'aktiven Prozess.
    
    RetVal = TerminateProcess(ProcessId_Exit, 1&)
    'Mit der TerminateProcess Funktion können Sie den ausgewählten
    'Prozess und all seine Threads (falls vorhanden) beenden.
    
    RetVal = CloseHandle(ProcessId_Exit)
    'Hier wird das Handle wieder geschlossen.
    
    Timer.Interval = 0
    
End Sub

'----- Ende Formular "frmProgRun" alias frmProgRun.frm  -----
'-------------- Ende Projektdatei tempprog.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 5 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.