Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0519: Auslesen einer Zeile in einer Textbox

VB 5/6-Tipp 0519: Auslesen einer Zeile in einer Textbox

 von Klaus Langbein

Schwierigkeitsgrad:

Verwendete API-Aufrufe: keine

Download: Download des Beispielprojektes [3,07 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Textfeld "Text1"
' Steuerelement: Beschriftungsfeld "lblLinePOs"
' Steuerelement: Beschriftungsfeld "LblPos"
' Steuerelement: Beschriftungsfeld "lblSelected"
' Steuerelement: Beschriftungsfeld "lblDescr" (Index von 0 bis 1)
'
' ---------------------------------------------------------
'
' Es ist des oefteren erforderlich eine einzelne Zeile
' aus einer Textbox auszulesen. Leider wurde die entsprechende
' API-Funktion in VB nicht implementiert. Hier wird gezeigt,
' wie diese Problem mit einfachen VB-Mitteln, ohne API, zu
' loesen ist.
'
' Autor: K. Langbein (Email: Klaus@ActiveVB)
'
' ---------------------------------------------------------
'
Option Explicit

Function PreviousCrlf(text As String, ByVal pos As Long) As Long
    ' In VB6 kann dies auch mit der Funktion InstrReverse
    ' gemacht werden.
    
    Dim i As Long
    Dim a As String
    
    For i = pos To 1 Step -1
    
        a = Mid$(text, i, 1)
        If Asc(a) = 10 Then
            If i > 1 Then
                a = Mid$(text, i - 1, 1)
                If Asc(a) = 13 Then
                    PreviousCrlf = i - 1
                    Exit For
                End If
            End If
        End If
        
    Next i
End Function

Function NextCrlf(text As String, ByVal pos As Long) As Long
    'Funktion zum auffinden des nächsten Zeilenumbruchs
    Dim i As Long
    
    If pos = 0 Then
        pos = 1
    End If
    
    i = InStr(pos, text, vbCrLf, vbBinaryCompare)
    If i > 0 Then
        NextCrlf = i
    End If
End Function

Function SelectLline(txt As Control) As String
    'Markiert die gesamte ausgewählte Zeile
    Dim pos As Long
    Dim pos1 As Long
    Dim pos2 As Long
    Dim a As String

    pos = txt.SelStart
    pos1 = PreviousCrlf(txt.text, pos)
    If pos1 = 0 Then
        pos1 = 1
    Else
        pos1 = pos1 + 2
    End If
    
    pos2 = NextCrlf(txt.text, pos)
    If pos2 = 0 Then
        pos2 = Len(txt.text)
    End If
    
    If pos2 > pos1 Then
        a = Mid$(txt.text, pos1, pos2 - pos1)
    End If
    
    txt.SelStart = pos1 - 1
    txt.SelLength = pos2 - pos1 + 1
    
    SelectLline = a
End Function

Sub ShowPos(txt As Control)
    LblPos.Caption = Format$(txt.SelStart)
    lblLinePOs.Caption = PreviousCrlf(txt.text, txt.SelStart)
End Sub

Private Sub Command1_Click()
   lblSelected.Caption = SelectLline(Text1)
End Sub

Private Sub Text1_Click()
    Call ShowPos(Text1)
End Sub

Private Sub Text1_KeyUp(KeyCode As Integer, Shift As Integer)
    Call ShowPos(Text1)
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Project1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 1 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.