Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0520: Alle in der Zwischenablage befindlichen Dateien auslesen

VB 5/6-Tipp 0520: Alle in der Zwischenablage befindlichen Dateien auslesen

 von Achim Neubauer

Schwierigkeitsgrad:

Verwendete API-Aufrufe: CloseClipboard, DragQueryFileA (DragQueryFile), GetClipboardData, IsClipboardFormatAvailable, OpenClipboard

Download: Download des Beispielprojektes [2,97 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Projekt1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Listen-Steuerelement "List1"
'
' Autor: Achim Neubauer (entrox@freak-style.de)

Option Explicit

Private Sub Command1_Click()
    Dim arrFiles() As String
    Dim T As Long
    
    If GetDragFilelist(Me.hwnd, arrFiles) > 0 Then
      For T = 1 To UBound(arrFiles)
        List1.AddItem arrFiles(T)
      Next T
    End If
End Sub

Private Sub Form_Load()
    Dim arrFiles() As String
    Dim T As Long
    
    If GetDragFilelist(Me.hwnd, arrFiles) > 0 Then
      For T = 1 To UBound(arrFiles)
        List1.AddItem arrFiles(T)
      Next T
    End If
End Sub

'---------- Ende Formular "Form1" alias Form1.frm  ----------
'--------- Anfang Modul "Module1" alias Module1.bas ---------
'
' Autor: Achim Neubauer (entrox@freak-style.de)

Option Explicit

Public Declare Function IsClipboardFormatAvailable Lib "user32" ( _
                        ByVal wFormat As Long) As Long
                        
Public Declare Function OpenClipboard Lib "user32" ( _
                        ByVal hwnd As Long) As Long
                        
Public Declare Function GetClipboardData Lib "user32" ( _
                        ByVal wFormat As Long) As Long
                        
Public Declare Function DragQueryFile Lib "shell32.dll" _
                        Alias "DragQueryFileA" ( _
                        ByVal hDrop As Long, _
                        ByVal UINT As Long, _
                        ByVal lpStr As String, _
                        ByVal ch As Long) As Long
                        
Public Declare Function CloseClipboard Lib "user32" () As Long

Public Const CF_HDROP = 15
Public Const MAX_PATH As Long = 260

Public Function GetDragFilelist(Handle As Long, arrFile() As String) As Long
    Dim hDrop As Long 'Handle auf die Clipboard-Daten
    Dim nFiles As Long 'Anzahl der Dateien in den Daten
    Dim FileName As String 'temporäre Variable
    Dim T As Long 'temporäre Variable
    Dim result As Long 'temporäre Variable
    
    ReDim arrFile(0)
    
    If IsClipboardFormatAvailable(CF_HDROP) Then 'Wenn Daten vom Typ CF_HDROP vorhanden sind
        Call OpenClipboard(0&) 'Clipboard öffnen
        hDrop = GetClipboardData(CF_HDROP) 'Handle auf Daten holen
        
        nFiles = DragQueryFile(hDrop, -1&, "", 0) 'Anzahl der Dateien abfragen
        
        ReDim arrFile(nFiles)
        
        For T = 0 To nFiles - 1
            FileName = Space(MAX_PATH)
            result = DragQueryFile(hDrop, T, FileName, Len(FileName)) 'Dateiname(T) holen
            
            arrFile(T + 1) = Left(FileName, result)
        Next T
    End If
    
    GetDragFilelist = nFiles 'Anzahl der geholten Dateien als Funktionswert  zurückliefern
    
    CloseClipboard 'Clipboard schließen
    
End Function
'---------- Ende Modul "Module1" alias Module1.bas ----------
'-------------- Ende Projektdatei Projekt1.vbp --------------

Archivierte Nutzerkommentare 

Klicken Sie diesen Text an, wenn Sie die 4 archivierten Kommentare ansehen möchten.
Diese stammen noch von der Zeit, als es noch keine direkte Forenunterstützung für Fragen und Kommentare zu einzelnen Artikeln gab.
Aus Gründen der Vollständigkeit können Sie sich die ausgeblendeten Kommentare zu diesem Artikel aber gerne weiterhin ansehen.