Die Community zu .NET und Classic VB.

Startseite / Tipps / VB 5/6-Tipp 0612: Mausspur ein-/ausschalten und deren Länge auslesen

VB 5/6-Tipp 0612: Mausspur ein-/ausschalten und deren Länge auslesen

 von Konrad Doblander

Schwierigkeitsgrad:

Verwendete API-Aufrufe: SystemParametersInfoA (SystemParametersInfo)

Download: Download des Beispielprojektes [2,34 KB]

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Projekt1.vbp -------------
'--------- Anfang Formular "Form1" alias Form1.frm  ---------
' Steuerelement: Schaltfläche "Command2"
' Steuerelement: Textfeld "Text1"
' Steuerelement: Schaltfläche "Command1"
' Steuerelement: Beschriftungsfeld "Label1"
Option Explicit



'Autor: Konrad Doblander
'Mail: Konrad@ActiveVB.de
'Überarbeitet von Jochen Wierum (JoWi@ActiveVB.de)

'Deklarationen
Private Declare Function SystemParametersInfo Lib "user32.dll" Alias _
                        "SystemParametersInfoA" (ByVal uAction As Long, _
                                                 ByVal uParam As Long, _
                                                 ByVal lpvParam As Long, _
                                                 ByVal fuWinIni As Long) As Long
                                                 
Private Const SPI_SETMOUSETRAILS As Long = &H5D '93
Private Const SPI_GETMOUSETRAILS As Long = &H5E '94

Public Function GetMouseTail() As Long
    Dim hTail As Long
    
    'Als lpvParam wird eine Variable übergeben, die die Länge des Tails
    'zugewiesen bekommt. Wenn diese größer als 1 ist, wird eine Mausspur
    'angezeigt
    Call SystemParametersInfo(SPI_GETMOUSETRAILS, 0&, VarPtr(hTail), 0&)
    
    If hTail <= 1 Then
        GetMouseTail = 0
    Else
        GetMouseTail = hTail
    End If
End Function

'Mausspur einstellen
Public Function SetMouseTail(ByRef MouseTailOn As Boolean, ByVal hTail As Long) As Boolean
    Dim rApi As Long
    
    If MouseTailOn Then
        'hTail = Anzahl d. Segemente
        rApi = SystemParametersInfo(SPI_SETMOUSETRAILS, hTail, 0&, 0&)
    Else
        rApi = SystemParametersInfo(SPI_SETMOUSETRAILS, 0&, 0&, 0&)
    End If
    
    'rAPI = 0 Fehler!
    SetMouseTail = (rApi > 0)
End Function

Private Sub Command1_Click()
    'Mausspur anzeigen
    SetMouseTail True, Val(Text1)
End Sub

Private Sub Command2_Click()
    'Mausspur ausblenden
    SetMouseTail False, 0
End Sub

Private Sub Form_Load()
    'Länge anzeigen
    Text1 = GetMouseTail
End Sub
'---------- Ende Formular "Form1" alias Form1.frm  ----------
'-------------- Ende Projektdatei Projekt1.vbp --------------